//===== eAthena Script ======================================= 
//= Quest NPCs related to Lutie
//===== By: ================================================== 
//= TonyMan & Samuray22
//===== Current Version: ===================================== 
//= 1.3b
//===== Compatible With: ===================================== 
//= eAthena 1.0
//===== Description: ========================================= 
//= Blush, Cake Hat, Candle, Chef Hat, Raccoon Hat, Rainbow Eggshell,
//= Spore Hat, Wonder Nutshell Quests
//===== Additional Comments: ================================= 
//= 1.1 Optimized [Lupus]
//= 1.2 Fixed Chef Hat items [Lupus]
//= 1.3 Update NPC to the Official One. [Samuray22]
//= 1.3a Changed item names to item IDs. [Samuray22]
//= 1.3b Removed a scrap " left in a delitem. [L0ne_W0lf]
//============================================================ 

xmas,117,295,3	script	Vending Machine Man	704,{
	mes "[Titicupe]";
	mes "Ha ha ha ha ha ha";
	mes "..You arrived";
	mes "I'm a manager";
	mes "of toy factory!!";
	mes "I've opened my eyes";
	mes "on new business!";
	next;
	switch(select( "Talk to him about the vending machine", "Items in the vending machine", "Stop talking")) {
	case 1:
		mes "[Titicupe]";
		mes "Can you see a little snowman";
		mes "left side of me. can you?";
		mes "If you look at his mouth cautiously";
		mes "you can find out";
		mes "that it was builted to";
		mes "huge size as it can";
		next;
		mes "[Titicupe]";
		mes "swallow any thing.";
		mes ".. feel bad hah?";
		mes "Try to put your";
		mes "hand,legs,and even your head inside.";
		mes "Everything goes in.";
		mes "Hohoho . However";
		next;
		mes "[Titicupe]";
		mes "this is a";
		mes "vending machine";
		mes "which is you can get";
		mes "fashionable decorating item.";
		mes "You have to provide";
		mes "some items when you want to get.";
		next;
		mes "[Titicupe]";
		mes "Pour out to snowman's mouth!!";
		mes "If you do that";
		mes "You can get";
		mes "fancy items wHat";
		mes "you dreamed for";
		mes "Ha ha ha ha ha~~~";
		next;
		goto L_end2;
	case 2:
		mes "[Titicupe]";
		mes "Ho ho ho ho~";
		mes "Do you have";
		mes "any question?";
		mes "then ask me";
		mes "I'm genius.ha ha~";
		next;
		switch( select( "Raccoon Hat", "Spore Hat", "Wonder Nutshell", "Rainbow Egg Shell", "Blush", "Chef Hat", "Candle", "Cake Hat", "Stop talking")) {
		case 1:
			mes "[Titicupe]";
			mes "Raccoon Hat ?";
			mes "Kitty Band 1";
			mes "Dragon Scale 20";
			mes "Tough Scalelike stem 200";
			mes "Sea-Otter Fur 300";
			goto L_end;
		case 2:
			mes "[Titicupe]";
			mes "Spore Hat ?";
			mes "Poison Spore 850";
			mes "Burnt Tree 300";
			mes "Long Tongue 1";
			goto L_end;
		case 3:
			mes "[Titicupe]";
			mes "Wonder Nutshell ?";
			mes "Fruit Shell 1";
			mes "Wing of Dragonfly 500";
			goto L_end;
		case 4:
			mes "[Titicupe]";
			mes "Rainbow Egg Shell ?";
			mes "Egg Shell 1";
			mes "Cobaltblue Dyestuffs 1";
			mes "Claw Of Desert Wolf 50";
			goto L_end;
		case 5:
			mes "[Titicupe]";
			mes "Blush ?!";
			mes "You !";
			mes "You know something ha ha ?!";
			mes "he he . anyway";
			mes "- Alice's Apron 100 -";
			goto L_end;
		case 6:
			mes "[Titicupe]";
			mes "Chef Hat ?";
			mes "Piece Of Cake 120";
			mes "White Dyestuffs 1";
			mes "Feather 330";
			mes "Dragon Scale 450";
			goto L_end;
		case 7:
			mes "[Titicupe]";
			mes "Candle ?";
			mes "Bomb Wick 1";
			mes "Matchstick 50";
			mes "Royal Jelly 100";
			goto L_end;
		case 8:
			mes "[Titicupe]";
			mes "Cake Hat ?";
			mes "Candy 10";
			mes "Candy Cane 5";
			mes "Well Baked Cookie 15";
			mes "Piece Of Cake 20";
			mes "steel 10";
			goto L_end;
		case 9:
			mes "[Titicupe]";
			mes "Ask me any time";
			mes " Actually you know?";
			mes "'Genius' knows everything ";
			mes "My brain is number one";
			mes "in the whole universe!";
			mes "Just So Goooooood!";
			goto L_end;
		}
	case 3:
		goto L_end2;
	}

L_end:
	next;
	mes "[Titicupe]";
	mes "So happy!!";
	mes "I'm a genius";
	mes "Ho ho ho";
	mes "Ho ho ho ho";
	close;
L_end2:
	mes "[Titicupe]";
	mes "I'm a genius!!";
	mes "The world will suprise!";
	mes "for my magnificient creation";
	mes "of these beautiful";
	mes "and so cool items";
	mes "Ke-ke-ke";
	next;
	mes "- Toy factory manager -";
	mes "- Titicupe is jumping -";
	mes "- around and pointing -";
	mes "- the vending machine -";
	mes "- snowman with very -";
	mes "- uproarious attitude-";
	mes "- and he looks very very happy -";
	close;
}

xmas,115,297,3	script	Vending Machine	111,{
	mes "[Audi]";
	mes "- Exciting item vending machine. -";
	mes "- Thanks to find Audi. -";
	mes "- Select a item that you want -";
	mes "- and -";
	mes "- Put required item to -";
	mes "- my mouth. -";
	next;
	switch( select( "^FF3355- notice (must read) -^000000", "Raccoon Hat", "Spore Hat", "Wonder Nutshell", "Rainbow Egg Shell", "Blush", "Hat Of Cooker", "Candle", "Cake Hat", "Cancel")) {
	case 1:
		mes "[Audi]";
		mes "Hi~ !";
		mes "I need to tell you";
		mes "one important thing";
		mes "This vending mashine is";
		mes "not equipted to differentiate";
		mes "special items and ordinary item";
		next;
		mes "[Audi]";
		mes "So If you use item that";
		mes "^FF3355already applied valuable";
		mes "Monster card in it^000000 or";
		next;
		mes "[Audi]";
		mes "^FF3355high level of";
		mes "forged items^000000 will";
		mes "^3355FFtreated as normal";
		mes "item^000000 so. When you";
		mes "try to exchange + generate item";
		mes "Please put away valiable items";
		next;
		mes "[Audi]";
		mes "to Kafre warehouse";
		mes "or seperate from";
		mes "your body.";
		mes "This is very important.";
		mes "Because if when you use";
		mes "this vending machine and";
		next;
		mes "[Audi]";
		mes "your valiable items";
		mes "have used by vending machine.";
		mes "There will be no";
		mes "refund and recover";
		mes "to that item.";
		next;
		mes "[Audi]";
		mes "Have a good time";
		mes "Thank you";
		close;
	case 2:
		if (countitem(2213) > 0 && countitem(1036) > 19 && countitem(7012) > 199 && countitem(7065) > 299) {
			callfunc "Vending Machine","good";
			next;
			delitem 2213, 1; //Kitty Band
			delitem 1036, 20; //Dragon Scale 
			delitem 7012, 200; //Tough Scalelike Stem
			delitem 7065, 300; //Sea-Otter Fur
			getitem 5033, 1; //Raccoon Hat
			callfunc "Vending Machine","finish";
		}
			callfunc "Vending Machine","bad";
	case 3:
		if (countitem(7033) > 849 && countitem(7068) > 299 && countitem(1015) > 0) {
			callfunc "Vending Machine","good";
			next;
			delitem 7033, 850; //Poison Spore
			delitem 7068, 300; //Burnt Tree
			delitem 1015, 1; //Tongue
			getitem 5029, 1; //Spore Hat
			callfunc "Vending Machine","finish";
		}
			callfunc "Vending Machine","bad";
	case 4:
		if (countitem(5037) > 0 && countitem(7064) > 499) {
			callfunc "Vending Machine","good";
			next;
			delitem 5037, 1; //Nutshell
			delitem 7064, 500; //Wing of Dragonfly
			getitem 5050, 1; //Wonder Nutshell
			callfunc "Vending Machine","finish";
		}
			callfunc "Vending Machine","bad";
	case 5:
		if (countitem(5015) > 0 && countitem(978) > 0 && countitem(7030) > 49) {
			callfunc "Vending Machine","good";
			next;
			delitem 5015, 1; //Egg Shell
			delitem 978, 1; //Cobaltblue Dyestuff
			delitem 7030, 50; //Claw of Desert Wolf
			getitem 5039, 1; //Rainbow Eggshell
			callfunc "Vending Machine","finish";
		}
			callfunc "Vending Machine","bad";
	case 6:
		if (countitem(7047) > 99) {
			callfunc "Vending Machine","good";
			next;
			delitem 7047, 100; //Alice's Apron
			getitem 5040, 1; //Blush
			callfunc "Vending Machine","finish";
		}
			callfunc "Vending Machine","bad";
	case 7:
		if (countitem(539) > 119 && countitem(982) > 0 && countitem(949) > 329 && countitem(1036) > 449) {
			callfunc "Vending Machine","good";
			next;
			delitem 539, 120; //Piece of Cake
			delitem 982, 1; //White Dyestuff
			delitem 949, 330; //Feather
			delitem 1036, 450; //Dragon Scale
			getitem 5026, 1; //Chef Hat
			callfunc "Vending Machine","finish";
		}
			callfunc "Vending Machine","bad";
	case 8:
		if (countitem(2279) > 0 && countitem(7035) > 49 && countitem(526) > 99) {
			callfunc "Vending Machine","good";
			next;
			delitem 2279, 1; //Bomb Wick
			delitem 7035, 50; //Matchstick
			delitem 526, 100; //Royal Jelly
			getitem 5028, 1; //Candle
			callfunc "Vending Machine","finish";
		}
			callfunc "Vending Machine","bad";
	case 9:
		if (countitem(529) > 9 && countitem(530) > 4 && countitem(538) > 14 && countitem(539) > 19 && countitem(999) > 9) {
			callfunc "Vending Machine","good";
			next;
			delitem 529, 10; //Candy
			delitem 530, 5; //Candy Cane
			delitem 538, 15; //Well-baked Cookie
			delitem 539, 20; //Piece of Cake
			delitem 999, 10; //Steel
			getitem 5024, 1; //Cake Hat
			callfunc "Vending Machine","finish";
		}
			callfunc "Vending Machine","bad";
	case 10:
		mes "[Audi]";
		mes "- Thank you so much -";
		mes "- for use me -";
		mes "- . . . . . -";
		mes "- But you didn't use";
		mes "- anything. hummmmm-";
		mes "- Well see you again ! -";
		close;
	}
}

function	script	Vending Machine	{
	if(getarg(0) == "good") {
		mes "- You put items -";
		mes "- that is required to -";
		mes "- generate new item, -";
		mes "- inside of me. hehe -";
		return;
	} else if(getarg(0) == "bad") {
		mes "[Audi]";
		mes "- Piiiiii !! -";
		mes "- Ups ! Ups ! -";
		mes "- lack of items -";
		mes "- Ups ! Ups ! -";
		mes "Don't think I'm fool.";
		close;
	}
		mes "[Audi]";
		mes "- broook boom -";
		mes "- boooom!! -";
		mes "- weck weck !! -";
		mes "- boom!! -";
		mes "- ugh ! -";
		if(countitem(5040) > 0) {
			mes "- Wow . Blush !! -";
			mes "- You are so cool -";
			mes "- you know real fashion ! -";
			mes "- ah so cute Blush -";
			mes "- Wanna touch .. -";
		}
		mes "- Thanks for use! -";
		close;
}

